Как сравнить пт 1 июля 05:21:23 2016 формат даты и времени в perl

Вы можете использовать DateTime::Format::Strptime для разбора строк в Datetime, поддерживающие сравнения:

use strict;
use warnings;
use feature 'say';
use DateTime::Format::Strptime;

my $strp = DateTime::Format::Strptime->new(pattern => '%a %b %d %H:%M:%S %Y');

my $dt1 = $strp->parse_datetime("Fri Jul 1 05:21:23 2016");
my $dt2 = $strp->parse_datetime("Sat Jul 2 05:21:23 2016");    

if ($dt1 < $dt2) {  # or use DateTime->compare()
    say '$dt1 < $dt2';
}
elsif ($dt1 == $dt2) {
    say '$dt1 == $dt2';
}
else {
    say '$dt1 > $dt2';
}

Используйте Time::Piece, чтобы преобразовать строки в объекты, которые можно сравнивать напрямую.

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

use Time::Piece;

my $date1 = 'Fri Jul 1 05:21:23 2016';
my $date2 = 'Thu Jun 30 12:00:00 2016';

my $date_format = '%a %b %d %H:%M:%S %Y';

my $tp1 = Time::Piece->strptime($date1, $date_format);
my $tp2 = Time::Piece->strptime($date2, $date_format);

if ($tp1 < $tp2) {
  say "$date1 is before $date2";
} elsif ($tp1 > $tp2) {
  say "$date1 is after $date2";
} else {
  say "$date1 is the same as $date2";
}